M5stick c Plus⇔Raspberry Pi 4B間BLE通信(旧情報)

#include <M5StickCPlus.h>
#include <BLEDevice.h>
#include <BLEServer.h>
#include <BLEUtils.h>
#include <esp_sleep.h>
#include "M5_ENV.h"


#define T_PERIOD 10 // アドバタイジングパケットを送る秒数
#define S_PERIOD 20 // Deep Sleepする秒数


SHT3X sht30;
QMP6988 qmp6988;


float temperature = 0.0;
float humidity = 0.0;
float pressure = 0.0;


RTC_DATA_ATTR static uint8_t seq; // 送信SEQ


// BLEデータを設定する関数
void setAdvData(BLEAdvertising *pAdvertising, float temperature, float humidity, float pressure) {
    BLEAdvertisementData oAdvertisementData = BLEAdvertisementData();


    // アドバタイジングパケットの設定
    oAdvertisementData.setFlags(0x06);


    std::string strServiceData = "";
    strServiceData += (char)0x0a; //長さ12byte
    strServiceData += (char)0xff; //AD Type
    strServiceData += (char)0xff; //会社ID(ここではダミーIDを使用)
    strServiceData += (char)0xff; //会社ID(ここではダミーIDを使用)
    strServiceData += (char)seq;  //シーケンス番号
    strServiceData += (char)((uint16_t)(temperature * 100) & 0xFF);        //温度の下位バイト
    strServiceData += (char)(((uint16_t)(temperature * 100) >> 8) & 0xFF); //温度の上位バイト
    strServiceData += (char)((uint16_t)(humidity * 100) & 0xFF);           //湿度の下位バイト
    strServiceData += (char)(((uint16_t)(humidity * 100) >> 8) & 0xFF);    //湿度の上位バイト
    strServiceData += (char)((uint16_t)(pressure / 100) & 0xFF);           //圧力の下位バイト
    strServiceData += (char)(((uint16_t)(pressure / 100) >> 8) & 0xFF);    //圧力の上位バイト


    oAdvertisementData.addData(strServiceData);
    pAdvertising->setAdvertisementData(oAdvertisementData);
}


// センサーデータをディスプレイに表示する関数
void displaySensorData(float temperature, float humidity, float pressure) {
    M5.Lcd.setCursor(0, 0, 1);
    M5.Lcd.printf("Temperature: %4.1f'C\r\n", temperature);
    M5.Lcd.printf("Humidity:    %4.1f%%\r\n", humidity);
    M5.Lcd.printf("Pressure:  %4.0fhPa\r\n", pressure);
}


void setup() {
    M5.begin();
    M5.Axp.ScreenBreath(10);
    M5.Lcd.setRotation(1);
    M5.Lcd.setTextSize(2);
    M5.Lcd.setTextColor(WHITE, BLACK);
    Wire.begin(32,33);
    sht30.init();
    qmp6988.init();


    pressure = qmp6988.calcPressure();
    if (sht30.get() == 0) {  
        temperature = sht30.cTemp;  
                           
        humidity = sht30.humidity;  
                               
    } else {
        temperature = 0, humidity = 0;
    }
   
    displaySensorData(temperature, humidity, pressure); // センサーデータをディスプレイに表示


    BLEDevice::init("blepub-01");
    BLEServer *pServer = BLEDevice::createServer();


    BLEAdvertising *pAdvertising = pServer->getAdvertising();
    setAdvData(pAdvertising, temperature, humidity, pressure); // BLEデータを設定


    pAdvertising->start();
    delay(T_PERIOD * 1000);
    pAdvertising->stop();


    seq++;
    delay(10);
    esp_deep_sleep(1000000LL * S_PERIOD);
}


void loop() {
    // このプログラムではloop()は使用されないので、何も記述しない
}